Asi budu vypadat jako hajzl, ale zkusili jste Google ? Tohle je snad jeden ze základních scriptů, který používá skoro každý...
Jinak si dle libosti upravte:
# automatizovany speedtest pro half-duplex spoje
# meri 10 sec upload, chvili pocka a meri 10 vterin download, vysledek posle mailem
# verze 1.1, 8.12.2020
# zadej jmeno a IP adresu ciloveho zarizeni
:local toname "Mujmikrotik"
:local toadress "123.123.123.123"
# a e-mail kam posilat vysledky
:local recipients {"mujkrasny@email.cz"; "dalsi@gmail.com" }
:local txc
:local txcA
:local txcB
:local txcC
:local rxc
:local rxcA
:local rxcB
:local rxcC
:local rxta
:local rxtaA
:local rxtaB
:local rxtaC
:local txta
:local txtaA
:local txtaB
:local txtaC
:local sysname [/system identity get name]
:local datetime "$[/system clock get date] $[/system clock get time]"
:log info "Bandwidth-test : $sysname <--> $toname start"
/tool bandwidth-test $toadress protocol=tcp direction=transmit connection-count=20 user=user password=moje-heslo duration=10s do={
:set txcA ($"tx-current" / 1000)
:set txcB ($txcA / 1000 * 1000)
:set txcC ($txcA - $txcB)
:set txcB ($txcB / 1000)
:set txc "$txcB.$txcC"
:set txtaA ($"tx-total-average" / 1000)
:set txtaB ($txtaA / 1000 * 1000)
:set txtaC ($txtaA - $txtaB)
:set txtaB ($txtaB / 1000)
:set txta "$txtaB.$txtaC"
}
:delay 5s
/tool bandwidth-test $toadress protocol=tcp direction=receive connection-count=20 user=user password=moje-heslo duration=10s do={
:set rxcA ($"rx-current" / 1000)
:set rxcB ($rxcA / 1000 * 1000)
:set rxcC ($rxcA - $rxcB)
:set rxcB ($rxcB / 1000)
:set rxc "$rxcB.$rxcC"
:set rxtaA ($"rx-total-average" / 1000)
:set rxtaB ($rxtaA / 1000 * 1000)
:set rxtaC ($rxtaA - $rxtaB)
:set rxtaB ($rxtaB / 1000)
:set rxta "$rxtaB.$rxtaC"
}
:log info "Bandwidth-test done, sending info by e-mail"
:foreach r in=$recipients do={
:put ("Sending email to " . [:tostr $r])
/tool e-mail send to=[:tostr $r] subject="Bandwidth-test done : $sysname <--> $toname" body="$sysname \n $datetime \n \n Result : \n TX speed $txc Mbps/s \n RX speed $rxc Mbps/s \n \n TX total average $txta Mbps/s \n RX total average $rxta Mbps/s"
}
Není to nic dokonalého, ale ubastlil jsem ho sám, hodně inspirován internetem, asi za 1/2 hodiny i s laděním....
